PROSAGA码农传奇-perl-将行与两个文件中的模式进行比较

<div class =“post-text”itemprop =“text”>
  <P>
    如果我理解你想要的输入数据
  </p>
  <UL>
    <LI>
      从文件1中读取行

<UL>
        <LI>
          过滤包含filter关键字的行
           <code>
            mti_clk_chk:
          </code>
        </LI>
        <LI>
          存储关键字后面的所有内容以进
        </LI>
      </UL>
    </LI>
    <LI>
      与文件2相同
    </LI>
    <LI>
      打印文件1中的行，其文件2中找不到比较字符串
    </LI>
    <LI>
      反之亦然，文件2
    </LI>
  </UL>
  <P>
    针对您的问题提出的解决方案：
  </p>
   <pre class="lang-perl prettyprint-override">
    <code>
      #!/usr/bin/perl
use warnings;
use strict;
use autodie;
use feature qw(say);

die "usage: $0 <log1> <log2>\n"
    if @ARGV < 2;
my($log1, $log2) = @ARGV;

# log file extractor function
sub extractor($) {
    my($file) = @_;
    my %lines;
    my @order;

# Parse log file contents
    open(my $fh, '<', $file);
    while (<$fh>) {
        chomp;
        if (my($key) = /mti_clk_chk:\s*(.+)$/) {
            die "duplicate log line '$_' detected at ${file}:$.!\n"
                if exists $lines{$key};
            $lines{$key} = $_;
            push(@order, $key);
        }
    }
    close($fh);

return((\%lines, \@order));
}

# parse log files
my($lines_log1, $order_log1) = extractor($log1);
my($lines_log2, $order_log2) = extractor($log2);

# lines in log1 but not in log2
say foreach (
    map  { $lines_log1->{$_} }
    grep { ! exists $lines_log2->{$_} }
    @{ $order_log1 }
);

# separator in output
say "";

# lines in log2 but not in log1
say foreach (
    map  { $lines_log2->{$_} }
    grep { ! exists $lines_log1->{$_} }
    @{ $order_log2 }
);

exit 0;

</code>
  </pre>
  <P>
    以您给出的两条线为例进行测试。我在开始和结束时添加了一些垃圾，以确保它不会以所需的输出结束。
  </p>
   <pre class="lang-none prettyprint-override">
    <code>
      $ cat dummy1.txt
test1
INFO @1102266 PHResourceLayer_Z4: mti_clk_chk:################ start of test ################ ; T=1102266
INFO @1102334 PHResourceLayer_Z4: mti_clk_chk:Checking the period of MTI, MTI10 clk from SV; T=1102334
test1

$ cat dummy2.txt
test2
UVM_INFO @1092507 reporter Z4_COREA: mti_clk_chk: ################ start of test ################ ; T=1092507
UVM_INFO @1092563 reporter Z4_COREA: mti_clk_chk: Checking the period of MTI, MTI10 clk from SV; T=1092563
test2

$ perl dummy.pl dummy1.txt dummy2.txt
INFO @1102266 PHResourceLayer_Z4: mti_clk_chk:################ start of test ################ ; T=1102266
INFO @1102334 PHResourceLayer_Z4: mti_clk_chk:Checking the period of MTI, MTI10 clk from SV; T=1102334

UVM_INFO @1092507 reporter Z4_COREA: mti_clk_chk: ################ start of test ################ ; T=1092507
UVM_INFO @1092563 reporter Z4_COREA: mti_clk_chk: Checking the period of MTI, MTI10 clk from SV; T=1092563

</code>
  </pre>
</DIV>