PROSAGA码农传奇-Windows-如何从两个文件夹中搜索特定文件，并比较使用批处理Windows脚本提供的相同或最新文件的时间戳

<div class =“post-text”itemprop =“text”>
  <P>
    您的意图并不十分清楚，特别是因为您所需的输出不明确，因为它不包含文件的父目录。
  </p>
  <P>
    无论如何，这是一个完成你想要的脚本（至少对我的理解），因为只有两个目录中存在的文件才能被处理。
  </p>
  <P>
    所以这是代码，包含几个解释
     <code>
      rem
    </code>
    -remarks：
  </p>
   <pre class="lang-cmd prettyprint-override">
    <code>
      @echo off
setlocal EnableExtensions DisableDelayedExpansion

rem // Define constants here:
set "_ROOT=%~dp0." & rem // (common root directory; `%~dp0.` is script's parent, `.` is current)
set "_DIR1=%_ROOT%\Directory1" & rem // (1st directory containing files)
set "_DIR2=%_ROOT%\Directory2" & rem // (2nd directory containing files)
set _MASKS="INV*." "SLS*."     & rem // (list of quoted file masks)
set "_TMP1=%TEMP%\%~n0_1_%RANDOM%.tmp" & rem // (1st temporary file)
set "_TMP2=%TEMP%\%~n0_2_%RANDOM%.tmp" & rem // (2nd temporary file)

rem // Resolve 1st directory to be an absolute path:
for %%E in ("%_DIR1%") do set "RDIR1=%%~fE"
rem // Resolve 2nd directory to be an absolute path:
for %%E in ("%_DIR2%") do set "RDIR2=%%~fE"

rem // Write all matching files in 1st directory to 1st temporary file:
pushd "%RDIR1%" && (
    for %%F in (%_MASKS%) do (
        echo(%%~nxF
    )
    popd
) > "%_TMP1%"
rem // Write all matching files in 2nd directory to 2nd temporary file:
pushd "%RDIR2%" && (
    for %%F in (%_MASKS%) do (
        echo(%%~nxF
    )
    popd
) > "%_TMP2%"

rem // Loop over all common files from both temporary files:
for /F %%L in ('findstr /L /I /X /G:"%_TMP1%" "%_TMP2%"') do (
    rem // Build absolute `wmic`-compatible file paths:
    set "FILE1=%RDIR1:\=\\%\\%%L" & set "FILE2=%RDIR2:\=\\%\\%%L"
    setlocal EnableDelayedExpansion
    rem set "FILE1=%!FILE1:&=&amp;!" & set "FILE2=%!FILE2:&=&amp;!"
    rem // Get standardised file date/time (last modification) of 1st file by `wmic`:
    for /F %%K in ('wmic DataFile where "Name='!FILE1!'" get LastModified') do set "DATE1=%%K"
    rem // Get standardised file date/time (last modification) of 2nd file by `wmic`:
    for /F %%K in ('wmic DataFile where "Name='!FILE2!'" get LastModified') do set "DATE2=%%K"
    rem // Compare file dates/times (last mod.) of both files and return differing ones:
    if !DATE1! leq !DATE2! echo "!FILE1:\\=\!" is older than "!FILE2:\\=\!"
    if !DATE1! gtr !DATE2! echo "!FILE1:\\=\!" is newer than "!FILE2:\\=\!"
    endlocal
)

rem // Clean up temporary files:
del "%_TMP1%" "%_TMP2%"

endlocal
exit /B

</code>
  </pre>
  <P>
    核心命令是：
  </p>
  <UL>
    <LI>
      <a href="http://ss64.com/nt/findstr.html" rel="nofollow noreferrer" title="FINDSTR">
         <code>
          findstr
        </code>
      </A>
      ，返回两个给定目录中常见的所有文件;
    </LI>
    <LI>
      <a href="http://ss64.com/nt/wmic.html" rel="nofollow noreferrer" title="WMIC.exe">
         <code>
          wmic
        </code>
      </A>
      ，以标准化的方式检索文件的最后修改日期/时间（格式为
       <code>
        YYYYMMDDhhmmss.uuuuuu+ZZZ
      </code>
      ），可以很容易地比较为字符串;
    </LI>
  </UL>
</DIV>