PROSAGA码农传奇-SAS-SAS ProcSQL 如何在SAS中执行Listagg功能

SAS ProcSQL 如何在SAS中执行Listagg功能

作者: 仙风道骨刘憨憨
发布时间: 2025-03-13 12:18:54 (2月前)
转自：

<div class =“post-text”itemprop =“text”>
  <P>
    以下是两个解决此问题的方法的示例：
  </p>
  <OL>
    <LI>
      是在数据步骤中执行此操作并在您执行时累积
    </LI>
    <LI>
      <P>
        将数据转换为宽格式，然后使用CAT函数。
      </p>
       <pre>
        <code>
          *create sample data for demonstration;
data have;
    infile cards dlm='09'x;
    input OrgID Product $   States $;
    cards;
1   football    DC
1   football    VA
1   football    MD
2   football    CA
3   football    NV
3   football    CA
;
run;

*Sort - required for both options;
proc sort data=have;
    by orgID;
run;

**********************************************************************;
*Use RETAIN and BY group processing to combine the information;
**********************************************************************;
data want_option1;
    set have;
    by orgID;
    length combined $100.;
    retain combined;

if first.orgID then
        combined=states;
    else
        combined=catx(', ', combined, states);

if last.orgID then
        output;
run;

**********************************************************************;
*Transpose it to a wide format and then combine into a single field;
**********************************************************************;
proc transpose data=have out=wide prefix=state_;
    by orgID;
    var states;
run;

data want_option2;
    set wide;
    length combined $100.;
    combined=catx(', ', of state_:);
run;

</code>
      </pre>
    </LI>
  </醇>
</DIV>