PROSAGA码农传奇-SAS-SAS - 根据更多变量的所有可能组合查找并分配ID

SAS - 根据更多变量的所有可能组合查找并分配ID

作者: 时间
发布时间: 2024-07-08 02:55:57 (4天前)
转自：

<div class =“post-text”itemprop =“text”>
  
    ID_NEW基于组合。每个独特的组合可以被认为是一个集合元素。 set元素是通过对数据值进行排序（将值排列转换为表示值组合的不同排列）并将它们与分隔符连接成单个值（即set元素）得到的。分隔确保了元素中贡献值的分离。 set元素也可以被认为是一个散列键，然后是单遍解决方案。
  
  
    例
  
   <pre>
 <code>
 perm sort element/key
A B C -> A B C -> A,B,C
B C A -> A B C -> A,B,C

</code>
 </pre>
  
     <code>
 CALL SORTC
 </code>
     将对变量进行排序，但您不希望对实际变量进行排序，因此必须将值复制到将要排序（并从输出中删除）的其他变量中
  
  
    一个
     <code>
 hash
 </code>
     可以将键值与combination_id相关联。每次遇到新的键值时，combo_id都会递增，或者当键已经存在时，它会被检索。
  
  
    例：
  
   <pre>
 <code>
 data HAVE;
input ID VAR1 $ VAR2 $ VAR3 $;
DATALINES;
001 A B C
002 A C B
003 B C A
004 A B .
005 B A .
006 D E F
007 E F D
008 F E D
009 E F .
010 F E .
011 C A B
012 E D F
RUN;

data want;
  if 0 then set have; * prep pdv;

length _key $100 combo_id 8; * host variables for hash;

if _n_ = 1 then do;
     declare hash ids();
     ids.defineKey ('_key');
     ids.defineData ('combo_id');
     ids.defineDone();
  end;

set have;

* copy data into variables that will be sorted;

* combination of raw data;
  * use cats in case some of variables are numeric;
  _item1 = cats(var1);
  _item2 = cats(var2);
  _item3 = cats(var3);

* alternative if combo_id is to be based on formatted data values;
  * use vvalue to obtained formatted representation of data values;
  * _item1 = vvalue(var1);
  * _item2 = vvalue(var2);
  * _item3 = vvalue(var3);

array items _item1-_item3;  * arrayify the _items so they can be sorted;

call sortc(of items(*));

* delimit with hex 255, a character not likely to occur
  * in the data value or formatted representation;

_key = catx('FF'x, of items(*));

* retrieve or increment the combo_id;

if ids.find() ne 0 then do;
    combo_id = ids.num_items + 1;
    ids.add();
  end;

drop _:;
run;

</code>
 </pre>
</DIV>